【シフトで！】360度どこでもなめらかにホーミングするミサイルを発射できる！エンティティホーミング機構の紹介【マイクラBE(Switch/Xbox/Win10/PS4)】【コマンド】【統合版】

コメント（9件）

スケルトンの魔法工房より:

2022年9月3日 8:12 PM

ホーミングミサイルのコマンド

▼概要

・データ値5の火打石を右手に持ってシフトをすることでミサイルが発射される。
　(/give @p flint 1 5)
・ミサイルは近くのモブに向かってホーミングしていく。
・モブに衝突、ブロックに衝突、10秒経過するとミサイルは爆発して周囲のモブに最大10のダメージを与える。

▼注意点

・新executeの使用。使う際はワールドの設定から「将来的なプレイ」をONにすること。
・オウム式シフト検知機構の使用。状況によってはまれに落下ダメージが無くなります。

▼コマンド本体

・/give @s command_block でコマンドブロックを手に入れられる
・すべて1列に繋げる
・初めのコマンドのみ反復　無条件　常にアクティブ
・それ以外のコマンドはすべて　チェーン　無条件　常にアクティブ

/scoreboard objectives add player_type_2 dummy
/scoreboard objectives add shift_time_2 dummy
/execute as @a unless entity @s[scores={player_type_2=..2147483647}] run scoreboard players add playerID player_type_2 1
/execute as @a unless entity @s[scores={player_type_2=..2147483647}] run scoreboard players operation @s player_type_2 = playerID player_type_2

/execute as @a[tag=motteru_flint_5] at @s positioned ^^^50 run summon parrot ~~1000~ minecraft:on_tame tori_2
/execute as @a at @s positioned ~~1000~ positioned ^^^50 run scoreboard players operation @e[name=tori_2,type=parrot,c=1] shift_time_2 = @s player_type_2
/execute as @a at @e[type=parrot,name=tori_2] if score @s player_type_2 = @e[type=parrot,name=tori_2,c=1] shift_time_2 run ride @e[type=parrot,name=tori_2,c=1] start_riding @s teleport_rider
/execute as @e[type=parrot,name=tori_2] at @s run tp @s 0 ~ 0
/execute as @e[type=parrot,name=tori_2] at @a if score @s shift_time_2 = @p player_type_2 positioned 0 ~1.22 0 if entity @s[r=0.1] run execute as @s at @a if score @s shift_time_2 = @p player_type_2 run scoreboard players add @p shift_time_2 1
/execute as @e[type=parrot,name=tori_2] at @a if score @s shift_time_2 = @p player_type_2 positioned 0 ~1.22 0 if entity @s[rm=0.1] run execute as @s at @a if score @s shift_time_2 = @p player_type_2 run scoreboard players set @p shift_time_2 0
/tp @e[type=parrot,name=tori_2] ~~-1000000~
/kill @e[type=parrot,name=tori_2]

/tag @a remove motteru_flint_5
/tag @a[hasitem={location=slot.weapon.mainhand,item=flint,data=5}] add motteru_flint_5
/execute as @a at @s if block ~~-0.1~ air 0 run tag @s remove motteru_flint_5

/tag @e add entity
/execute as @a[tag=motteru_flint_5,scores={shift_time_2=1}] at @s run summon boat ^^^-50
/scoreboard objectives add misairu_boat dummy
/execute as @a[tag=motteru_flint_5,scores={shift_time_2=1}] at @s positioned ^^^-50 at @e[type=boat,tag=!entity,c=1] run tp @e[c=1] ^^^ facing @s
/execute as @a[tag=motteru_flint_5,scores={shift_time_2=1}] at @s positioned ^^^-50 run scoreboard players add @e[type=boat,tag=!entity,c=1] misairu_boat 1

/execute as @e[scores={misairu_boat=1}] at @s positioned ~~1001.5~ run tp @s ^^^51
/execute as @e[scores={misairu_boat=1}] at @s positioned ~~-1000~ run playsound random.explode @a ~~~ 0.5 0.7
/execute as @e[scores={misairu_boat=1}] at @s run particle minecraft:explosion_particle ~~-1000~

/scoreboard players add @e[scores={misairu_boat=1..}] misairu_boat 1

/execute as @e[scores={misairu_boat=1..}] at @s run execute at @e[family=mob,c=1,y=~-1000] positioned ~~1000~ positioned ^10000^^ if entity @s[r=10000] at @s run tp @s ~~~~2
/execute as @e[scores={misairu_boat=1..}] at @s run execute at @e[family=mob,c=1,y=~-1000] positioned ~~1000~ positioned ^-10000^^ if entity @s[r=10000] at @s run tp @s ~~~~-2
/execute as @e[scores={misairu_boat=1..}] at @s run execute at @e[family=mob,c=1,y=~-1000] positioned ~~1000~ positioned ^^-10000^ if entity @s[r=10000] at @s run tp @s ~~~~~-3
/execute as @e[scores={misairu_boat=1..}] at @s run execute at @e[family=mob,c=1,y=~-1000] positioned ~~1000~ positioned ^^10000^ if entity @s[r=10000] at @s run tp @s ~~~~~3
/execute as @e[scores={misairu_boat=1..}] at @s run tp @s ^^^0.5
/execute as @e[scores={misairu_boat=1..}] at @s run particle minecraft:endrod ~~-1000~

/execute as @e[scores={misairu_boat=1..}] at @s unless block ~~-999.7~ air 0 run scoreboard players set @s misairu_boat -1
/execute as @e[scores={misairu_boat=1..}] at @s positioned ~~-1000~ if entity @e[family=mob,r=1.5] run scoreboard players set @s misairu_boat -1
/scoreboard players set @e[scores={misairu_boat=200..}] misairu_boat -1

/execute as @e[scores={misairu_boat=-1}] at @s run particle minecraft:huge_explosion_emitter ~~-1000~
/execute as @e[scores={misairu_boat=-1}] at @s positioned ~~-1000~ run damage @e[r=3.5,family=mob] 5 suicide entity @s
/execute as @e[scores={misairu_boat=-1}] at @s positioned ~~-1000~ run damage @e[r=1.5,family=mob] 5 suicide entity @s
/execute as @e[scores={misairu_boat=-1}] at @s positioned ~~-1000~ run playsound random.explode @a ~~~ 0.5 0.7
/kill @e[scores={misairu_boat=-1}]

/execute as @a at @s at @e[family=mob,c=1] positioned ^-10000^^ if entity @s[r=10000] at @s run playsound random.click @a

返信
匿名より:

2022年9月3日 8:12 PM

at式スコア一致検知機構を使ってロックオン機能を作れば…
妄想が止まらん←作れ()

返信
コマンド勢&ゲーム再現者メインより:

2022年9月3日 8:12 PM

新executeでランダムチェストをコマンドブロックでしてください
宜しくお願いします。

返信
JIN より:

2022年9月3日 8:12 PM

2147483647(コマンド3つめ)ってなんですか？

返信
トワヤン333 より:

2022年9月3日 8:12 PM

すご！
めちゃかっこいい！

返信
たけやんより:

2022年9月3日 8:12 PM

早速シフト機構使ってる
やっぱり便利やわ

返信
M Toguchi より:

2022年9月3日 8:12 PM

なるほど！！全部理解！(できない)

返信
ミヤビ砲より:

2022年9月3日 8:12 PM

でもそういえばこの新executeってまだベータ版じゃなかったっけ
はやく実装されないかな

返信
佐藤信子より:

2022年9月3日 8:12 PM

大体は理解できるけど、いざこれを組み立てる、または、改造しようとしたら脳が追いつかない……
こんなすごいことできたり思いつける人は滅多にいない…

返信

【シフトで！】360度どこでもなめらかにホーミングするミサイルを発射できる！エンティティホーミング機構の紹介【マイクラBE(Switch/Xbox/Win10/PS4)】【コマンド】【統合版】

マイクラ動画カテゴリの最新記事

〇〇した人のドロッパー[マインクラフト]#shorts #マイクラ #minecraft

アイテムがおかしい魔法の授業 #shorts

突発配信！！！アツクラ大富豪への道！【マイクラ/ゆっくり】#アツクラ

Summon Enderman‼︎2エンダーマン召喚2#マインクラフト #minecraft#マイクラ#minecraftfunny

最後まで息を止めれてら神 #minecraft #マイクラ #shorts #マインクラフト #ゆっくり #まいくら

勝てないから地形を利用して倒す！！#pvp #マイクラ #マインクラフト