【マイクラ統合版コマンド】反射魔法！誤差の無い完璧な挙動の跳ね返り【スイッチ対応】【近似無し】【RPG】

コメント（3件）

にゃんくん (NYANKUN) より:

2023年8月25日 9:12 PM

・事前準備
一度だけ実行してください

scoreboard objectives add e dummy

scoreboard objectives add bound_magic dummy

・本体のコマンド
①の1つ目のコマンドだけリピートにして，①～⑥までを全て連続してチェーン常時実行でつなげて下さい！

①entityの番号振り（５コマンド）
scoreboard players add @e e 0

scoreboard players operation max e > * e

execute as @e[tag=!e_set,scores={e=0}] at @e[tag=!e_set,scores={e=0}] run scoreboard players add @s e 1

scoreboard players operation @e[tag=!e_set,scores={e=0..}] e += max e

tag @e[tag=!e_set,scores={e=0..}] add e_set

②召喚（５コマンド）
execute at @e[type=snowball] as @p[y=~-0.5] at @s anchored eyes positioned ~ ~10000 ~ run summon boat ~ ~ ~ facing ^ ^ ^1

execute at @e[type=snowball] as @p[y=~-0.5] at @s anchored eyes positioned ~ ~10000 ~ run scoreboard players operation @e[type=boat,tag=!bound_magic,c=1] e = @s e

execute at @e[type=snowball] as @p[y=~-0.5] at @s anchored eyes positioned ~ ~10000 ~ run tag @e[type=boat,tag=!bound_magic,c=1] add bound_magic

tag @e[tag=bound_magic] add e_set

kill @e[type=snowball]

③寿命（２コマンド）
scoreboard players add @e[tag=bound_magic] bound_magic 1

kill @e[tag=bound_magic,scores={bound_magic=200..}]

④進行（２コマンド）
execute at @e[tag=bound_magic] positioned ~ ~-10000 ~ run particle minecraft:blue_flame_particle

execute as @e[tag=bound_magic] at @s run tp @s ^ ^ ^0.2

⑤反射（３コマンド）
execute as @e[tag=bound_magic] at @s positioned 0 0 0 positioned ^ ^ ^2 positioned 0 ~ ~ positioned ^ ^ ^-1 facing 0 0 0 positioned as @s positioned ^ ^ ^0.1 rotated as @s positioned ^ ^ ^0.1 unless block ~ ~-10000 ~ air positioned 0 0 0 positioned ^ ^ ^2 positioned 0 ~ ~ positioned ^ ^ ^-1 facing 0 0 0 facing ^ ^ ^-1 positioned as @s run tp @s ~ ~ ~ ~ ~

execute as @e[tag=bound_magic] at @s positioned 0 0 0 positioned ^ ^ ^2 positioned ~ ~ 0 positioned ^ ^ ^-1 facing 0 0 0 positioned as @s positioned ^ ^ ^0.1 rotated as @s positioned ^ ^ ^0.1 unless block ~ ~-10000 ~ air positioned 0 0 0 positioned ^ ^ ^2 positioned ~ ~ 0 positioned ^ ^ ^-1 facing 0 0 0 facing ^ ^ ^-1 positioned as @s run tp @s ~ ~ ~ ~ ~

execute as @e[tag=bound_magic] at @s positioned ^ ^ ^0.1 rotated ~180 ~ positioned ^ ^ ^0.1 unless block ~ ~-10000 ~ air facing ^ ^ ^-1 run tp @s ~ ~ ~ ~ ~

⑥ヒット（３コマンド）
execute as @e[tag=bound_magic] at @s positioned ~ ~-10000 ~ as @e[x=~-0.99,y=~-0.99,z=~-0.99,dx=0,dy=0,dz=0] as @s[dx=0,dy=0,dz=0] unless score @s e = @e[tag=bound_magic,y=~10000,c=1] e run playsound random.explode @a ~ ~ ~ 0.3 1.5 0.0

execute as @e[tag=bound_magic] at @s positioned ~ ~-10000 ~ as @e[x=~-0.99,y=~-0.99,z=~-0.99,dx=0,dy=0,dz=0] as @s[dx=0,dy=0,dz=0] unless score @s e = @e[tag=bound_magic,y=~10000,c=1] e run particle minecraft:sonic_explosion

execute as @e[tag=bound_magic] at @s positioned ~ ~-10000 ~ as @e[x=~-0.99,y=~-0.99,z=~-0.99,dx=0,dy=0,dz=0] as @s[dx=0,dy=0,dz=0] unless score @s e = @e[tag=bound_magic,y=~10000,c=1] e run damage @s 5 magic entity @e[tag=bound_magic,y=~10000,c=1]

※④⑤⑥をさらに繋げていくと弾が速くなります
例) ①②③④⑤⑥④⑤⑥④⑤⑥④⑤⑥ これで1tickに0.8マス進むようになります
T O より:

2023年8月25日 9:12 PM

コマンドを貼って欲しいです
りーより:

2023年8月25日 9:12 PM

かっこいい