【統合版】アクロバットに宙を舞う！「ジャンプパッド」を簡単に設置できるコマンド【マイクラBE(Switch/Xbox/Win10/PS4)】【コマンド】

コメント（9件）

スケルトンの魔法工房より:

2022年4月30日 2:12 PM

動画のFPSががががが
コマンドはｺﾁﾗです↓↓↓(長文注意)

ジャンプパッドのコマンド

▼概要

・スライムブロックがジャンプパッドになる
・3×3のスペースがないと展開できずにアイテム化する
・ジャンプパッドの上を走り抜けると前方に吹き飛ぶ
・ジャンプパッドの上でジャンプすると上空に吹き飛ぶ
・ジャンプパッドの階段部分を壊すとアイテム化する
・ジャンプパッドの角部分にブロックを置くとアイテム化する
・たくさん置けます(置きすぎると重くなります)

▼注意

・スライムブロックが建築に使えなくなる
・スライムブロックにつけた名前は保持されない
・ジャンプするときのエフェクトのレベルはかな～り適当
　自分で調節することをお勧めします

▼コマンド本体

・最初のコマンドは　反復　無条件　常にアクティブ
・それ以外のコマンドは　チェーン　無条件　常にアクティブ
・すべて一列に繋げる
・コマンド群ごとに区別するために改行がされていますが気にしないでください
・何か間違い、バグが見つかったら報告お願いします

/scoreboard objectives add jump_now dummy
/scoreboard objectives add okeru_count dummy

/tag @e add entity
/execute @a ~~~ fill ~10~10~10~-10~-10~-10 air 0 replace composter 8
/tag @e[tag=!entity] add item_composter

/execute @a ~~~ fill ~10~10~10~-10~-10~-10 composter 8 replace slime
/execute @a ~~~ fill ~10~10~10~-10~-10~-10 air 0 replace composter 8
/tag @e[tag=!entity,tag=!item_composter] add slime_block

/execute @e[tag=slime_block] ~~~ fill ~1~~1~-1~~-1 composter 8 keep
/execute @e[tag=slime_block] ~~~ fill ~1~~1~-1~~-1 air 0 replace composter 8
/tag @e[tag=!entity,tag=!item_composter,tag=!slime_block] add koppun
/execute @e[tag=!entity,tag=!item_composter,tag=!slime_block] ~~~ scoreboard players add @e[c=1,tag=slime_block] okeru_count 1
/execute @e[tag=slime_block,scores={okeru_count=!9}] ~~~ setblock ~~~ slime 0
/execute @e[tag=slime_block,scores={okeru_count=!9}] ~~~ setblock ~~~ air 0 destroy
/execute @e[tag=slime_block,scores={okeru_count=!9}] ~~~ tag @e[tag=!slime_block,tag=!koppun,tag=!entity,tag=!composter_item,c=1,type=item] add kesanaide_drop
/execute @e[tag=slime_block,scores={okeru_count=!9}] ~~~ particle minecraft:egg_destroy_emitter ~~~
/execute @e[tag=slime_block,scores={okeru_count=!9}] ~~~ playsound random.click @a ~~~ 1 1.6
/kill @e[tag=slime_block,scores={okeru_count=!9}]

/execute @e[tag=slime_block] ~~~ setblock ~1~~ blackstone_stairs 1
/execute @e[tag=slime_block] ~~~ setblock ~~~-1 blackstone_stairs 2
/execute @e[tag=slime_block] ~~~ setblock ~~~1 blackstone_stairs 3
/execute @e[tag=slime_block] ~~~ setblock ~-1~~ blackstone_stairs 0
/execute @e[tag=slime_block] ~~~ setblock ~~~ sealantern
/execute @e[tag=slime_block] ~~~ playsound mob.enderdragon.flap @a ~~~ 0.6 1.5
/execute @e[tag=slime_block] ~~~ particle minecraft:knockback_roar_particle ~~~

/execute @a ~~~ fill ~10~10~10~-10~-10~-10 composter 8 replace sealantern
/execute @a ~~~ fill ~10~10~10~-10~-10~-10 air 0 replace composter 8
/execute @e[tag=!entity,tag=!item_composter,tag=!slime_block,tag=!kesanaide_drop,tag=!koppun] ~~~ setblock ~~~ sealantern 0

/execute @e[tag=!entity,tag=!item_composter,tag=!slime_block,tag=!kesanaide_drop,tag=!koppun] ~~~ detect ~1~~ blackstone_stairs 1 execute @s ~~~ detect ~~~-1 blackstone_stairs 2 execute @s ~~~ detect ~~~1 blackstone_stairs 3 execute @s ~~~ detect ~-1~~ blackstone_stairs 0 tag @s add omaeha_patto
/tag @e[tag=!entity,tag=!item_composter,tag=!slime_block,tag=!kesanaide_drop,tag=!koppun] add sealantern

/tag @a[tag=zimen_tuiteru] add zimen_tuita
/execute @a[tag=zimen_tuiteru] ~~~ detect ~~-0.1~ air 0 tag @s remove zimen_tuita

/execute @e[tag=omaeha_patto] ~~~ scoreboard players set @a[tag=!zimen_tuita,tag=zimen_tuiteru,r=1.6] jump_now 0

/tag @a add zimen_tuiteru
/execute @a ~~~ detect ~~-0.1~ air 0 tag @s remove zimen_tuiteru

/execute @e[tag=sealantern] ~~~ fill ~1~~1~-1~~-1 composter 8 keep
/execute @e[tag=sealantern] ~~~ fill ~1~~1~-1~~-1 air 0 replace composter 8
/tag @e[tag=!entity,tag=!item_composter,tag=!slime_block,tag=!sealantern,tag=!kesanaide_drop,tag=!koppun] add tigau_koppun
/execute @e[tag=tigau_koppun] ~~~ scoreboard players add @e[c=1,tag=sealantern] okeru_count 1
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ setblock ~~~ slime 0

/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ setblock ~~~1 air 0
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ setblock ~1~~ air 0
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ setblock ~~~-1 air 0
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ setblock ~-1~~ air 0

/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ fill ~1~~1~-1~~-1 air 0 destroy
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ tag @e[tag=!entity,tag=!item_composter,tag=!slime_block,tag=!sealantern,tag=!kesanaide_drop,tag=!koppun,tag=!tigau_koppun,r=2,type=item] add kesanaide_drop
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ particle minecraft:knockback_roar_particle ~~~
/execute @e[tag=sealantern,scores={okeru_count=!4}] ~~~ playsound mob.zombie.woodbreak @a ~~~ 0.6 2

/execute @e[tag=item_composter] ~~~ setblock ~~~ composter 8
/kill @e[tag=!entity,tag=!kesanaide_drop]

/scoreboard players add @a[scores={jump_now=0..}] jump_now 1
/effect @a[scores={jump_now=1}] levitation 1 150 true
/effect @a[scores={jump_now=2}] levitation 0 0 true
/effect @a[scores={jump_now=1}] speed 1 200 true
/effect @a[scores={jump_now=2}] speed 0 0 true
/execute @a[scores={jump_now=..20}] ~~~ particle minecraft:endrod ~~~
/execute @a[scores={jump_now=1}] ~~~ playsound random.explode @a ~~~ 0.7 2
/execute @a[scores={jump_now=1}] ~~~ particle minecraft:dragon_death_explosion_emitter ~~~
/effect @a[scores={jump_now=15}] slow_falling 3 0 true

一言

「いちいちスコア作成の文章打ち込むのめんどくさい…
　→反復コマンドに組み込めばよくね？！
　　→結果…上のコマンドを参照」

返信
ひなぴ〜より:

2022年4月30日 2:12 PM

僕スイッチなんですけどスイッチでコピペってできたらいいですけどできないですよね？このコマンドをやってみたいんですがどうすればいいですか？やる方法わかる人教えてくれませんか？（長文失礼しました）

返信
だいふくより:

2022年4月30日 2:12 PM

scoreboarb このコマンドが存在し、これを使用する権限があることを確認してくださいて出ました

返信
にしおかファミリーより:

2022年4月30日 2:12 PM

エリトラをつけたらhiveのデスランの羽みたいになるコマンド作ってください

返信
るんのチャンネルより:

2022年4月30日 2:12 PM

ウポルトン！！

録画ミス？

返信
synsyun nーn より:

2022年4月30日 2:12 PM

クオリティー高けー
コマンド長げー

返信
T commander より:

2022年4月30日 2:12 PM

なぜゲーム登録がマイクラじゃないのだろうか…スケルトンの魔法工房七不思議？

返信
それなは? より:

2022年4月30日 2:12 PM

最初のクリーパーさんが使ってた剣のコマンド教えてほしいw

返信
ああああより:

2022年4月30日 2:12 PM

このラグさはまずそう…
録画ソフト変えたりしてみました？

返信